set DEFAULT_DNPATH=C:\inetpub\scripts\dnet
set DEFAULT_DNNEOPATH=C:\inetpub\scripts\dneo

echo off

echo ----------------------------------------------
echo  start migration tool!!
echo ----------------------------------------------
echo;

echo  移行ツールを実行しますか？
set ANS=
set /p ANS="実行します(yes)/実行しない(no): "

if /i %ANS% == yes (
	echo;
) else (
	echo 移行ツールを終了します。
	goto :EOF
)


set DNPATH=
set /p DNPATH="desknet's のインストールパスを入力してください。 (default: %DEFAULT_DNPATH%): "
if ""%DNPATH%""=="""" (
	set DNPATH=%DEFAULT_DNPATH%
)

if not exist %DNPATH% (
	echo ERROR: desknet's install directory not found
	goto :EOF
)
echo;

set DNNEOPATH=
set /p DNNEOPATH="desknet's NEO のインストールパスを入力してください。 (default: %DEFAULT_DNNEOPATH%): "
if ""%DNNEOPATH%""=="""" (
	set DNNEOPATH=%DEFAULT_DNNEOPATH%
)

if not exist %DNNEOPATH% (
	echo ERROR: desknet's NEO install directory not found
	goto :EOF
)
echo;

echo desknet's インストールパス : %DNPATH%
echo desknet's NEO インストールパス : %DNNEOPATH%
echo;

set DATA_DNPATH=%DNPATH%\dncs\data
set DATA_DNNEOPATH=%DNNEOPATH%\dncs\data

SETLOCAL ENABLEDELAYEDEXPANSION 
if exist %DATA_DNNEOPATH% (
	echo バックアップを作成します
	
	set BACKUP_DNNEOPATH=%DNNEOPATH%\dncs\backup
	if not exist !BACKUP_DNNEOPATH! (
		echo バックアップディレクトリを作成 : !BACKUP_DNNEOPATH!\
		mkdir !BACKUP_DNNEOPATH!
	)
	
	set TEMPDATE=%date:~-10,4%%date:~-5,2%%date:~-2,2%
	set TEMPTIME2=%time: =0%
	set TEMPTIME=!TEMPTIME2:~0,2!%time:~3,2%%time:~6,2%
	set BACKUPFILE_DNNEOPATH=!BACKUP_DNNEOPATH!\data.!TEMPDATE!!TEMPTIME!
	echo バックアップ : !BACKUPFILE_DNNEOPATH!
	xcopy /i /e %DATA_DNNEOPATH% !BACKUPFILE_DNNEOPATH!
	echo;
)
ENDLOCAL

echo 移行処理を開始します
echo;

if not exist %DATA_DNNEOPATH%\system (
	echo システムディレクトリを作成 : %DATA_DNNEOPATH%\system\
	mkdir %DATA_DNNEOPATH%\system
)
echo システム情報をコピー : %DATA_DNPATH%\system\system
copy %DATA_DNPATH%\system\system %DATA_DNNEOPATH%\system\system
echo;

if not exist %DATA_DNNEOPATH%\users (
	echo ユーザディレクトリを作成 : %DATA_DNNEOPATH%\users\
	mkdir %DATA_DNNEOPATH%\users
)
echo ユーザ一覧情報をコピー : %DATA_DNPATH%\\users\users
copy %DATA_DNPATH%\users\users %DATA_DNNEOPATH%\users\users
echo;

set USER_DNPATH=
set USER_DNNEOPATH=
SETLOCAL ENABLEDELAYEDEXPANSION 
for /F "usebackq" %%d in (`dir /ad /b %DNPATH%\dncs\data\users`) do (
	echo ユーザ : %%d
	
	set USER_DNPATH=%DATA_DNPATH%\users\%%d
	set USER_DNNEOPATH=%DATA_DNNEOPATH%\users\%%d
	if not exist !USER_DNNEOPATH! (
		echo   ユーザディレクトリを作成 : !USER_DNNEOPATH!\
		mkdir !USER_DNNEOPATH!
	)
	
	if exist !USER_DNPATH!\user (
		echo   ユーザ情報をコピー : !USER_DNPATH!\user
		copy !USER_DNPATH!\user !USER_DNNEOPATH!\.
	)
	
	if exist !USER_DNPATH!\auth (
		echo   認証情報をコピー : !USER_DNPATH!\auth
		copy !USER_DNPATH!\auth !USER_DNNEOPATH!\.
	)

	if exist !USER_DNNEOPATH!\desknets_user (
		echo   ユーザキャッシュ情報を削除 : !USER_DNNEOPATH!\desknets_user
		del !USER_DNNEOPATH!\desknets_user
	)
	
	if exist !USER_DNNEOPATH!\calendar (
		echo   カレンダー情報を削除 : !USER_DNNEOPATH!\calendar
		del !USER_DNNEOPATH!\calendar
	)

	if exist !USER_DNNEOPATH!\calendar_link (
		echo   カレンダー紐付け情報を削除 : !USER_DNNEOPATH!\calendar_link
		del !USER_DNNEOPATH!\calendar_link
	)

	echo;
)
ENDLOCAL

echo;
echo 移行処理が完了しました
echo;
